1 AC_INIT([filter-admdscrub], [v0.3], [misc@opensmtpd.org], [filter-admdscrub], [https://src.imperialat.at/?action=summary&path=filter-admdscrub.git])
2 AC_CONFIG_AUX_DIR(etc)
3 AC_CONFIG_LIBOBJ_DIR(compat)
4 AC_CANONICAL_HOST
5 AM_INIT_AUTOMAKE([-Wall foreign subdir-objects])
6 AC_PROG_CC
7 AC_USE_SYSTEM_EXTENSIONS
8 
9 AC_ARG_WITH([libexecsmtpddir],
10 	[AS_HELP_STRING([--with-libexecsmtpddir=DIR], ["OpenSMTPD libexec binary location [LIBEXECDIR/smtpd]"])],
11 	[libexecsmtpddir=$withval],
12 	[libexecsmtpddir="\${libexecdir}/smtpd"])
13 AC_SUBST([libexecsmtpddir], [$libexecsmtpddir])
14 
15 PKG_PROG_PKG_CONFIG
16 
17 AC_REPLACE_FUNCS([fgetln strtonum reallocarray recallocarray strcasestr])
18 
19 AC_CHECK_FUNC([pledge])
20 
21 dnl on OpenBSD, make sure to use libevent from base
22 case "$host_os" in
23 *openbsd*)
24 	AC_SEARCH_LIBS([event_init], [event], [],
25 		[AC_MSG_ERROR([requires libevent])])
26 	;;
27 *)
28 	PKG_CHECK_MODULES([libevent2], [libevent_core >= 2], [
29 		AC_DEFINE([HAVE_EVENT2], 1, [1 if using event2])
30 		CFLAGS="$libevent2_CFLAGS $CFLAGS"
31 		LIBS="$libevent2_LIBS $LIBS"
32 	], [AC_MSG_ERROR([requires libevent])])
33 	;;
34 esac
35 
36 AC_SEARCH_LIBS([osmtpd_run], [opensmtpd], [], [
37 	AC_MSG_ERROR([cannot find libopensmtpd])
38 ])
39 
40 # check compiler flags
41 AC_DEFUN([CC_ADD_CHECK_FLAGS], [
42 	AC_MSG_CHECKING([if $CC supports $1 flag])
43 	old_CFLAGS="$CFLAGS"
44 	CFLAGS="$CFLAGS -Werror $1"
45 	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], [
46 		AC_MSG_RESULT(yes)
47 		CFLAGS="$old_CFLAGS $1"
48 	], [
49 		AC_MSG_RESULT(no)
50 		CFLAGS="$old_CFLAGS"
51 	])
52 ])
53 CC_ADD_CHECK_FLAGS([-Wall])
54 CC_ADD_CHECK_FLAGS([-Wstrict-prototypes])
55 CC_ADD_CHECK_FLAGS([-Wmissing-prototypes])
56 CC_ADD_CHECK_FLAGS([-Wmissing-declarations])
57 CC_ADD_CHECK_FLAGS([-Wshadow])
58 dnl CC_ADD_CHECK_FLAGS([-Wcast-qual])
59 CC_ADD_CHECK_FLAGS([-Wpointer-arith])
60 CC_ADD_CHECK_FLAGS([-Wsign-compare])
61 
62 CC_ADD_CHECK_FLAGS([-Wno-pointer-sign])
63 CC_ADD_CHECK_FLAGS([-Wno-unused-function])
64 CC_ADD_CHECK_FLAGS([-Wno-deprecated-declarations])
65 
66 AC_SUBST([AM_CFLAGS])
67 AC_CONFIG_HEADERS([config.h])
68 AC_CONFIG_FILES([GNUmakefile])
69 
70 AC_OUTPUT